VB en Réseau

NETBIOS

Récupérer l'adresse MAC du poste local

Pour utiliser l'exemple, il faut créer un nouveau projet sous VB et rajouter les fichiers suivants :

Pour arriver à mes fins, j'utilise trois commandes NETBIOS : NCBENUM, NCBRESET et NCBASTAT.

LANA (LAN Adapter) : Composant réseau

NCBENUM : Donne le nombre de LANA(composant réseau). Quand ce code est spécifié, NCB_BUFFER pointe sur une zone tampon (buffer) rempli avec la structure LANA_ENUM.

NCBRESET : Réinitialise un composant réseau. Un composant DOIT être réinitialisé avant n'importe quelles commande NETBIOS (sauf NCBENUM).

NCBASTAT : Donne l'etat du composant réseau.Quand ce code est spécifié, NCB_BUFFER pointe sur une zone tampon (buffer) rempli avec la structure ADAPTER_STATUS, suivi par un tableau de structure NAME_BUFFER.

Je précise qu'il s'agit juste d'un exemple pour comprendre le concept général.

Pour toutes questions : webmaster@vbenreseau.com

NbtstatLocal.frm

Option Explicit

Private Sub Command1_Click()

Dim NCB As NET_CONTROL_BLOCK
Dim Lana As LANA_ENUM
Dim AST As ASTAT
Dim result As Integer
Dim i As Integer
Dim j As Integer
Dim k As Integer
Dim x As Integer
Dim tTyp As String
Dim tMac As String
Dim tName As String
Dim tFlag As Integer
Dim tFlag_Name As String
Dim tFlag_Name1 As String
Dim Zone As String
NCB.ncb_buffer = VarPtr(Lana)
NCB.ncb_length = Len(Lana)
NCB.ncb_command = NCBENUM
result = Netbios(NCB)
Debug.Print "result = "; result

For i = 0 To Lana.Length - 1
'NCB.ncb_command = NCBRESET
'result = Netbios(NCB)
'If result <> 0 Then
' MsgBox "Reset Result = " & Str$(result)
' Exit Sub
'End If
NCB.ncb_command = NCBASTAT
NCB.ncb_buffer = VarPtr(AST)
NCB.ncb_length = Len(AST)
NCB.ncb_callname = "* "
NCB.ncb_lana_num = Lana.Lana(i)
result = Netbios(NCB)
If result = 0 Then
Zone = Zone & " NetBIOS Machine Name Table" & vbCrLf & vbCrLf
Zone = Zone & "Name" & vbTab & vbTab & "Type" & vbTab & vbTab & _
"Status" & vbCrLf
Zone = Zone & _
"---------------------------------------------------------------------------------" _
& vbCrLf
tMac = ""
For x = 0 To 5
tMac = tMac & Format$(Hex$(AST.adapt.adapter_address(x)), "00") & "."
Next x

For j = 0 To AST.adapt.name_count - 1
tName = ""
For x = 0 To 14
tName = tName & Chr$(AST.NameBuff(j).name1(x))
Next x
Debug.Print "Name" & x & " = " & tName
tTyp = Format$(AST.NameBuff(j).name1(15), "00")
tFlag = htons(AST.NameBuff(j).name_flags)
If Int((tFlag / 256) And &H80) = &H80 Then
tFlag_Name = " GROUP"
Else
tFlag_Name = " UNIQUE"
End If
If Int((tFlag / 256) And &H10) = &H10 Then tFlag_Name1 = "DeRegistering"
If Int((tFlag / 256) And &H8) = &H8 Then tFlag_Name1 = "Name Conflict"
If Int((tFlag / 256) And &H4) = &H4 Then tFlag_Name1 = "Registered"
If Int((tFlag / 256) And &H2) = &H2 Then tFlag_Name1 = "Permanent Name"
Zone = Zone & tName & vbTab & "<" & tTyp & ">" & _
tFlag_Name & vbTab & tFlag_Name1 & vbCrLf
Next j
Zone = Zone & vbCrLf & "MAC Address = " & Left$(tMac, 17) & vbCrLf & vbCrLf
Else
MsgBox "Error # : " & result
End If
Next i
Text1 = Zone

End Sub

NetbiosLocal.bas

Option Explicit

Public Const NCBNAMSZ As Long = 16

Public Const NCBACTION = &H77
Public Const NCBADDGRNAME = &H36
Public Const NCBADDNAME = &H30
Public Const NCBCALL = &H10
Public Const NCBCANCEL = &H35
Public Const NCBCHAINSEND = &H17
Public Const NCBCHAINSENDNA = &H72
Public Const NCBDELNAME = &H31
Public Const NCBDGRECV = &H21
Public Const NCBDGRECVBC = &H23
Public Const NCBDGSEND = &H20
Public Const NCBDGSENDBC = &H22
Public Const NCBENUM = &H37
Public Const NCBFINDNAME = &H78
Public Const NCBHANGUP = &H12
Public Const NCBLANSTALERT = &H73
Public Const NCBLISTEN = &H11
Public Const NCBRECV = &H15
Public Const NCBRECVANY = &H16
Public Const NCBSEND = &H14
Public Const NCBSENDNA = &H71
Public Const NCBSSTAT = &H34
Public Const NCBTRACE = &H79
Public Const NCBUNLINK = &H70
Public Const NCBASTAT = &H33
Public Const NCBRESET = &H32

Public Type NET_CONTROL_BLOCK 'NCB
ncb_command As Byte
ncb_retcode As Byte
ncb_lsn As Byte
ncb_num As Byte
ncb_buffer As Long
ncb_length As Integer
ncb_callname As String * NCBNAMSZ
ncb_name As String * NCBNAMSZ
ncb_rto As Byte
ncb_sto As Byte
ncb_post As Long
ncb_lana_num As Byte
ncb_cmd_cplt As Byte
ncb_reserve(9) As Byte ' Reserved, must be 0
ncb_event As Long
End Type
Public Type ADAPTER_STATUS
adapter_address(5) As Byte
rev_major As Byte
reserved0 As Byte
adapter_type As Byte
rev_minor As Byte
duration As Integer
frmr_recv As Integer
frmr_xmit As Integer
iframe_recv_err As Integer
xmit_aborts As Integer
xmit_success As Long
recv_success As Long
iframe_xmit_err As Integer
recv_buff_unavail As Integer
t1_timeouts As Integer
ti_timeouts As Integer
Reserved1 As Long
free_ncbs As Integer
max_cfg_ncbs As Integer
max_ncbs As Integer
xmit_buf_unavail As Integer
max_dgram_size As Integer
pending_sess As Integer
max_cfg_sess As Integer
max_sess As Integer
max_sess_pkt_size As Integer
name_count As Integer
End Type
Public Type NAME_BUFFER
name1(15) As Byte
name_num As Byte
name_flags As Byte
End Type
Public Type ASTAT
adapt As ADAPTER_STATUS
NameBuff(30) As NAME_BUFFER
End Type

Public Const MAX_LANA = 254

Type LANA_ENUM
Length As Byte
Lana(MAX_LANA) As Byte
End Type

Declare Function htons Lib "wsock32.dll" _
(ByVal a As Integer) As Integer

Public Declare Function Netbios Lib "netapi32.dll" _
(pncb As NET_CONTROL_BLOCK) As Byte

Public Declare Sub CopyMemory Lib "Kernel32" Alias "RtlMoveMemory" _
(hpvDest As Any, hpvSource As Any, ByVal cbCopy As Long)